Rules for integrands involving (((a+b ArcTan[c x]))^p)

4.  ∫(((f x))^m)(((d+e x))^q) (((a+b ArcTan[c x]))^p)dx  when  p∈(SuperPlus[ℤ])

1.  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0

1:  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0 ∧ m>0

Derivation: Algebraic expansion

Basis: (x/(d+e x))==(1/e)-(d/(e (d+e x)))

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0 ∧ m>0, then

∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(d+e x))dx  ⟶  (f/e)∫(((f x))^(m-1)) (((a+b ArcTan[c x]))^p)dx-((d f)/e)∫(((((f x))^(m-1)) (((a+b ArcTan[c x]))^p))/(d+e x))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  f/e*Int[(f*x)^(m-1)*(a+b*ArcTan[c*x])^p,x] - 
  d*f/e*Int[(f*x)^(m-1)*(a+b*ArcTan[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2+e^2,0] && GtQ[m,0]

Int[(f_.*x_)^m_.*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  f/e*Int[(f*x)^(m-1)*(a+b*ArcCot[c*x])^p,x] - 
  d*f/e*Int[(f*x)^(m-1)*(a+b*ArcCot[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2+e^2,0] && GtQ[m,0]

2.  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0 ∧ m<0

1:  ∫((((a+b ArcTan[c x]))^p)/(x(d+e x)))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0

Derivation: Integration by parts

Basis: (1/(x (d+e x)))==(1/d) (∂_x)Log[2-(2/(1+((e x)/d)))]

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0, then

∫((((a+b ArcTan[c x]))^p)/(x(d+e x)))dx  ⟶  (((((a+b ArcTan[c x]))^p) Log[2-(2/(1+((e x)/d)))])/d)-((b c p)/d)∫(((((a+b ArcTan[c x]))^(p-1)) Log[2-(2/(1+((e x)/d)))])/(1+(c^2)(x^2)))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./(x_*(d_+e_.*x_)),x_Symbol] :=
  (a+b*ArcTan[c*x])^p*Log[2-2/(1+e*x/d)]/d - 
  b*c*p/d*Int[(a+b*ArcTan[c*x])^(p-1)*Log[2-2/(1+e*x/d)]/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d^2+e^2,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./(x_*(d_+e_.*x_)),x_Symbol] :=
  (a+b*ArcCot[c*x])^p*Log[2-2/(1+e*x/d)]/d + 
  b*c*p/d*Int[(a+b*ArcCot[c*x])^(p-1)*Log[2-2/(1+e*x/d)]/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[c^2*d^2+e^2,0]

2:  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(d+e x))dx  when  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0 ∧ m<-1

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(1/d)-((e x)/(d (d+e x)))

Rule: If  p∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0 ∧ m<-1, then

∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(d+e x))dx  ⟶  (1/d)∫(((f x))^m) (((a+b ArcTan[c x]))^p)dx-(e/(d f))∫(((((f x))^(m+1)) (((a+b ArcTan[c x]))^p))/(d+e x))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcTan[c*x])^p,x] - 
  e/(d*f)*Int[(f*x)^(m+1)*(a+b*ArcTan[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2+e^2,0] && LtQ[m,-1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcCot[c*x])^p,x] - 
  e/(d*f)*Int[(f*x)^(m+1)*(a+b*ArcCot[c*x])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,f},x] && IGtQ[p,0] && EqQ[c^2*d^2+e^2,0] && LtQ[m,-1]

2:  ∫(((f x))^m)(((d+e x))^q)(a+b ArcTan[c x])dx  when  q≠-1 ∧ 2 m∈ℤ ∧ ((m|q)∈(SuperPlus[ℤ]) ∨ m+q+1∈(SuperMinus[ℤ])∧ m q<0)

Derivation: Integration by parts

Rule: If  q≠-1 ∧ 2 m∈ℤ ∧ ((m|q)∈(SuperPlus[ℤ]) ∨ m+q+1∈(SuperMinus[ℤ])∧ m q<0), let u->∫(((f x))^m) (((d+e x))^q)dx, then

∫(((f x))^m) (((d+e x))^q) (a+b ArcTan[c x])dx  ⟶  u(a+b ArcTan[c x])-b c∫(u/(1+(c^2)(x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_.*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcTan[c*x]),u] - b*c*Int[SimplifyIntegrand[u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && NeQ[q,-1] && IntegerQ[2*m] && (IGtQ[m,0] && IGtQ[q,0] || ILtQ[m+q+1,0] && LtQ[m*q,0])

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_.*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcCot[c*x]),u] + b*c*Int[SimplifyIntegrand[u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && NeQ[q,-1] && IntegerQ[2*m] && (IGtQ[m,0] && IGtQ[q,0] || ILtQ[m+q+1,0] && LtQ[m*q,0])

3:  ∫(((f x))^m) (((d+e x))^q)(((a+b ArcTan[c x]))^p)dx  when  p-1∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0 ∧ (m|q)∈ℤ ∧ q≠-1

Derivation: Integration by parts

Rule: If  p-1∈(SuperPlus[ℤ])∧ (c^2) (d^2)+(e^2)==0 ∧ (m|q)∈ℤ ∧ q≠-1, let u->∫(((f x))^m) (((d+e x))^q)dx, then

∫(((f x))^m) (((d+e x))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  
u(((a+b ArcTan[c x]))^p)-b c p∫(((a+b ArcTan[c x]))^(p-1)) ExpandIntegrand[(u/(1+(c^2)(x^2))),x] dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_,x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcTan[c*x])^p,u] - b*c*p*Int[ExpandIntegrand[(a+b*ArcTan[c*x])^(p-1),u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && IGtQ[p,1] && EqQ[c^2*d^2+e^2,0] && IntegersQ[m,q] && NeQ[m,-1] && NeQ[q,-1] && ILtQ[m+q+1,0] && LtQ[m*q,0]

Int[(f_.*x_)^m_.*(d_.+e_.*x_)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_,x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x)^q,x]},
  Dist[(a+b*ArcCot[c*x])^p,u] + b*c*p*Int[ExpandIntegrand[(a+b*ArcCot[c*x])^(p-1),u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,q},x] && IGtQ[p,1] && EqQ[c^2*d^2+e^2,0] && IntegersQ[m,q] && NeQ[m,-1] && NeQ[q,-1] && ILtQ[m+q+1,0] && LtQ[m*q,0]

4:  ∫(((f x))^m)(((d+e x))^q) (((a+b ArcTan[c x]))^p)dx  when  p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ (q>0 ∨ a≠0 ∨ m∈ℤ)

Rule: If  p∈(SuperPlus[ℤ])∧ q∈ℤ ∧ (q>0 ∨ a≠0 ∨ m∈ℤ), then

∫(((f x))^m)(((d+e x))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  ∫(((a+b ArcTan[c x]))^p) ExpandIntegrand[(((f x))^m)(((d+e x))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTan[c*x])^p,(f*x)^m*(d+e*x)^q,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0] && IntegerQ[q] && (GtQ[q,0] || NeQ[a,0] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCot[c*x])^p,(f*x)^m*(d+e*x)^q,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && IGtQ[p,0] && IntegerQ[q] && (GtQ[q,0] || NeQ[a,0] || IntegerQ[m])

5.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx

1.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d

1.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q>0

1:  ∫(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  e==(c^2) d ∧ q>0

Rule: If  e==(c^2) d ∧ q>0, then

∫(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  ⟶  -((b(((d+e (x^2)))^q))/(2 c q(2q+1)))+((x (((d+e (x^2)))^q) (a+b ArcTan[c x]))/(2q+1))+((2 d q)/(2 q+1))∫(((d+e (x^2)))^(q-1)) (a+b ArcTan[c x])dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  -b*(d+e*x^2)^q/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcTan[c*x])/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcTan[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[q,0]

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  b*(d+e*x^2)^q/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcCot[c*x])/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcCot[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[q,0]

2:  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q>0 ∧ p>1

Rule: If  e==(c^2) d ∧ q>0 ∧ p>1, then

∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  

-((b p(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p-1)))/(2 c q(2q+1)))+(( x (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p))/(2q+1))+
((2d q)/(2q+1)) ∫(((d+e (x^2)))^(q-1)) (((a+b ArcTan[c x]))^p)dx+(((b^2)d p(p-1))/(2q(2q+1))) ∫(((d+e (x^2)))^(q-1)) (((a+b ArcTan[c x]))^(p-2))dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_,x_Symbol] :=
  -b*p*(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p-1)/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcTan[c*x])^p/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcTan[c*x])^p,x] + 
  b^2*d*p*(p-1)/(2*q*(2*q+1))*Int[(d+e*x^2)^(q-1)*(a+b*ArcTan[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[q,0] && GtQ[p,1]

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_,x_Symbol] :=
  b*p*(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p-1)/(2*c*q*(2*q+1)) + 
  x*(d+e*x^2)^q*(a+b*ArcCot[c*x])^p/(2*q+1) + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*ArcCot[c*x])^p,x] + 
  b^2*d*p*(p-1)/(2*q*(2*q+1))*Int[(d+e*x^2)^(q-1)*(a+b*ArcCot[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[q,0] && GtQ[p,1]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<0

1.  ∫((((a+b ArcTan[c x]))^p)/(d+e (x^2)))dx  when  e==(c^2) d

x:  ∫((((a+b ArcTan[c x]))^p)/(d+e (x^2)))dx  when  e==(c^2) d

Derivation: Integration by substitution

Basis: If  e==(c^2) d, then ((F[ArcTan[c x]])/(d+e (x^2)))==(1/(c d)) Subst[F[x],x,ArcTan[c x]] (∂_x)ArcTan[c x]

Rule: If  e==(c^2) d, then

∫((((a+b ArcTan[c x]))^p)/(d+e (x^2)))dx  ⟶  (1/(c d)) Subst[∫(((a+b x))^p)dx,x,ArcTan[c x]]

Program code:

(* Int[(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/(c*d)*Subst[Int[(a+b*x)^p,x],x,ArcTan[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] *)

(* Int[(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  -1/(c*d)*Subst[Int[(a+b*x)^p,x],x,ArcCot[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] *)

1:  ∫(1/((d+e (x^2))(a+b ArcTan[c x])))dx  when  e==(c^2) d

Derivation: Integration by substitution

Rule: If  e==(c^2) d, then

∫(1/((d+e (x^2))(a+b ArcTan[c x])))dx  ⟶  ((Log[a+b ArcTan[c x]])/(b c d))

Program code:

Int[1/((d_+e_.*x_^2)*(a_.+b_.*ArcTan[c_.*x_])),x_Symbol] :=
  Log[RemoveContent[a+b*ArcTan[c*x],x]]/(b*c*d) /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d]

Int[1/((d_+e_.*x_^2)*(a_.+b_.*ArcCot[c_.*x_])),x_Symbol] :=
  -Log[RemoveContent[a+b*ArcCot[c*x],x]]/(b*c*d) /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d]

2:  ∫((((a+b ArcTan[c x]))^p)/(d+e (x^2)))dx  when  e==(c^2) d ∧ p≠-1

Derivation: Integration by substitution

Rule: If  e==(c^2) d ∧ p≠-1, then

∫((((a+b ArcTan[c x]))^p)/(d+e (x^2)))dx  ⟶  ((((a+b ArcTan[c x]))^(p+1))/(b c d(p+1)))

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTan[c*x])^(p+1)/(b*c*d*(p+1)) /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && NeQ[p,-1]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  -(a+b*ArcCot[c*x])^(p+1)/(b*c*d*(p+1)) /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && NeQ[p,-1]

2.  ∫((((a+b ArcTan[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])

1.  ∫((((a+b ArcTan[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ n∈(SuperPlus[ℤ])∧ d>0

1:  ∫(((a+b ArcTan[c x]))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ d>0

Derivation: Integration by substitution and algebraic simplification

Note: Although not essential, these rules returns antiderivatives free of complex exponentials of the form  i (e^(ArcTan[c x])) and  (e^(ArcCot[c x])).

Basis: If  e==(c^2) d ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==(1/(c(Sqrt[d]))) Sec[ArcTan[c x]] (∂_x)ArcTan[c x]

Basis: If  e==(c^2) d ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==-(1/(c(Sqrt[d])))(Sqrt[((Csc[ArcCot[c x]])^2)]) (∂_x)ArcCot[c x]

Rule: If  e==(c^2) d ∧ d>0, then

∫((a+b ArcTan[c x])/(Sqrt[d+e (x^2)]))dx  ⟶  (1/(c(Sqrt[d])))Subst[(a+b x)Sec[x],x,ArcTan[c x]]
  ⟶  -((2 i (a+b ArcTan[c x]) ArcTan[((Sqrt[1+i c x])/(Sqrt[1-i c x]))])/(c (Sqrt[d])))+((i b PolyLog[2,-((i (Sqrt[1+i c x]))/(Sqrt[1-i c x]))])/(c (Sqrt[d])))-((i b PolyLog[2,((i (Sqrt[1+i c x]))/(Sqrt[1-i c x]))])/(c (Sqrt[d])))

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -2*I*(a+b*ArcTan[c*x])*ArcTan[Sqrt[1+I*c*x]/Sqrt[1-I*c*x]]/(c*Sqrt[d]) + 
  I*b*PolyLog[2,-I*Sqrt[1+I*c*x]/Sqrt[1-I*c*x]]/(c*Sqrt[d]) - 
  I*b*PolyLog[2,I*Sqrt[1+I*c*x]/Sqrt[1-I*c*x]]/(c*Sqrt[d]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[d,0]

Int[(a_.+b_.*ArcCot[c_.*x_])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -2*I*(a+b*ArcCot[c*x])*ArcTan[Sqrt[1+I*c*x]/Sqrt[1-I*c*x]]/(c*Sqrt[d]) - 
  I*b*PolyLog[2,-I*Sqrt[1+I*c*x]/Sqrt[1-I*c*x]]/(c*Sqrt[d]) + 
  I*b*PolyLog[2,I*Sqrt[1+I*c*x]/Sqrt[1-I*c*x]]/(c*Sqrt[d]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[d,0]

2.  ∫((((a+b ArcTan[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0

1:  ∫((((a+b ArcTan[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution

Basis: If  e==(c^2) d ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==(1/(c(Sqrt[d]))) Sec[ArcTan[c x]] (∂_x)ArcTan[c x]

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcTan[c x]))^p)/(Sqrt[d+e (x^2)]))dx  ⟶  (1/(c(Sqrt[d]))) Subst[∫(((a+b x))^p)Sec[x]dx,x,ArcTan[c x]]

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/(c*Sqrt[d])*Subst[Int[(a+b*x)^p*Sec[x],x],x,ArcTan[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcCot[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  e==(c^2) d ∧ d>0, then (1/(Sqrt[d+e (x^2)]))==-(1/(c(Sqrt[d])))(((Csc[ArcCot[c x]])^2)/(Sqrt[((Csc[ArcCot[c x]])^2)])) (∂_x)ArcCot[c x]

Basis: (∂_x)((Csc[x])/(Sqrt[((Csc[x])^2)]))==0

Basis: ((Csc[ArcCot[c x]])/(Sqrt[((Csc[ArcCot[c x]])^2)]))==((c x(Sqrt[1+(1/((c^2) (x^2)))]))/(Sqrt[1+(c^2)(x^2)]))

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcCot[c x]))^p)/(Sqrt[d+e (x^2)]))dx  ⟶ - (1/(c(Sqrt[d]))) Subst[∫(((((a+b x))^p)((Csc[x])^2))/(Sqrt[((Csc[x])^2)]))dx,x,ArcCot[c x]]                                        
                        ⟶ - ((x(Sqrt[1+(1/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))Subst[∫(((a+b x))^p)Csc[x]dx,x,ArcCot[c x]]

Program code:

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  -x*Sqrt[1+1/(c^2*x^2)]/Sqrt[d+e*x^2]*Subst[Int[(a+b*x)^p*Csc[x],x],x,ArcCot[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcTan[c x]))^p)/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d≯0

Derivation: Piecewise constant extraction

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d≯0, then

∫((((a+b ArcTan[c x]))^p)/(Sqrt[d+e (x^2)]))dx  ⟶  ((Sqrt[1+(c^2)(x^2)])/(Sqrt[d+e (x^2)]))∫((((a+b ArcTan[c x]))^p)/(Sqrt[1+(c^2)(x^2)]))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcTan[c*x])^p/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && Not[GtQ[d,0]]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcCot[c*x])^p/Sqrt[1+c^2*x^2],x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && Not[GtQ[d,0]]

3.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<-1

1:  ∫((((a+b ArcTan[c x]))^p)/(((d+e (x^2)))^2))dx  when  e==(c^2) d ∧ p>0

Rule: If  e==(c^2) d ∧ p>0, then

∫((((a+b ArcTan[c x]))^p)/(((d+e (x^2)))^2))dx  ⟶  ((x (((a+b ArcTan[c x]))^p))/(2 d (d+e (x^2))))+((((a+b ArcTan[c x]))^(p+1))/(2b c (d^2)(p+1)))-((b c p)/2)∫((x (((a+b ArcTan[c x]))^(p-1)))/(((d+e (x^2)))^2))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  x*(a+b*ArcTan[c*x])^p/(2*d*(d+e*x^2)) + 
  (a+b*ArcTan[c*x])^(p+1)/(2*b*c*d^2*(p+1)) - 
  b*c*p/2*Int[x*(a+b*ArcTan[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  x*(a+b*ArcCot[c*x])^p/(2*d*(d+e*x^2)) - 
  (a+b*ArcCot[c*x])^(p+1)/(2*b*c*d^2*(p+1)) + 
  b*c*p/2*Int[x*(a+b*ArcCot[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<-1 ∧ p≥1

1.  ∫(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  e==(c^2) d ∧ q<-1

1:  ∫((a+b ArcTan[c x])/(((d+e (x^2)))^(3/2)))dx  when  e==(c^2) d

Rule: If  e==(c^2) d, then

∫((a+b ArcTan[c x])/(((d+e (x^2)))^(3/2)))dx  ⟶  (b/(c d(Sqrt[d+e (x^2)])))+((x (a+b ArcTan[c x]))/(d(Sqrt[d+e (x^2)])))

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  b/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcTan[c*x])/(d*Sqrt[d+e*x^2]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d]

Int[(a_.+b_.*ArcCot[c_.*x_])/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  -b/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcCot[c*x])/(d*Sqrt[d+e*x^2]) /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d]

2:  ∫(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  e==(c^2) d ∧ q<-1 ∧ q≠-(3/2)

Rule: If  e==(c^2) d ∧ q<-1 ∧ q≠-(3/2), then

∫(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  ⟶  ((b(((d+e (x^2)))^(q+1)))/(4 c d (((q+1))^2)))-((x (((d+e (x^2)))^(q+1)) (a+b ArcTan[c x]))/(2d(q+1)))+((2q+3)/(2 d(q+1)))∫(((d+e (x^2)))^(q+1)) (a+b ArcTan[c x])dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  b*(d+e*x^2)^(q+1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && NeQ[q,-3/2]

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  -b*(d+e*x^2)^(q+1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && NeQ[q,-3/2]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<-1 ∧ p>1

1:  ∫((((a+b ArcTan[c x]))^p)/(((d+e (x^2)))^(3/2)))dx  when  e==(c^2) d ∧ p>1

Rule: If  e==(c^2) d ∧ p>1, then

∫((((a+b ArcTan[c x]))^p)/(((d+e (x^2)))^(3/2)))dx  ⟶  ((b p (((a+b ArcTan[c x]))^(p-1)))/(c d(Sqrt[d+e (x^2)])))+((x (((a+b ArcTan[c x]))^p))/(d(Sqrt[d+e (x^2)])))-(b^2)p(p-1)∫((((a+b ArcTan[c x]))^(p-2))/(((d+e (x^2)))^(3/2)))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  b*p*(a+b*ArcTan[c*x])^(p-1)/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcTan[c*x])^p/(d*Sqrt[d+e*x^2]) -
  b^2*p*(p-1)*Int[(a+b*ArcTan[c*x])^(p-2)/(d+e*x^2)^(3/2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,1]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  -b*p*(a+b*ArcCot[c*x])^(p-1)/(c*d*Sqrt[d+e*x^2]) +
  x*(a+b*ArcCot[c*x])^p/(d*Sqrt[d+e*x^2]) -
  b^2*p*(p-1)*Int[(a+b*ArcCot[c*x])^(p-2)/(d+e*x^2)^(3/2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,1]

2:  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<-1 ∧ p>1 ∧ q≠-(3/2)

Rule: If  e==(c^2) d ∧ q<-1 ∧ p>1 ∧ q≠-(3/2), then

∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  
((b p (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^(p-1)))/(4 c d(((q+1))^2)))-((x (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p))/(2 d(q+1)))+
((2 q+3)/(2 d(q+1)))∫(((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p)dx-(((b^2)p(p-1))/(4(((q+1))^2)))∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p-2))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_,x_Symbol] :=
  b*p*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^(p-1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p,x] -
  b^2*p*(p-1)/(4*(q+1)^2)*Int[(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && GtQ[p,1] && NeQ[q,-3/2]

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_,x_Symbol] :=
  -b*p*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^(p-1)/(4*c*d*(q+1)^2) -
  x*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p/(2*d*(q+1)) +
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p,x] -
  b^2*p*(p-1)/(4*(q+1)^2)*Int[(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p-2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && GtQ[p,1] && NeQ[q,-3/2]

3:  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<-1 ∧ p<-1

Derivation: Integration by parts

Basis: If  e==(c^2) d, then ((((a+b ArcTan[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTan[c x]))^(p+1))/(b c d(p+1)))

Rule: If  e==(c^2) d ∧ q<-1 ∧ p<-1, then

∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  (((((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^(p+1)))/(b c d(p+1)))-((2 c (q+1))/(b(p+1)))  ∫x (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p+1))dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_,x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^(p+1)/(b*c*d*(p+1)) - 
  2*c*(q+1)/(b*(p+1))*Int[x*(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && LtQ[p,-1]

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_,x_Symbol] :=
  -(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^(p+1)/(b*c*d*(p+1)) + 
  2*c*(q+1)/(b*(p+1))*Int[x*(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && LtQ[p,-1]

4.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])

1.  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])

1:  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0)

Derivation: Integration by substitution

Basis: If  e==(c^2) d ∧ 2 (q+1)∈ℤ ∧ (q∈ℤ ∨ d>0), then (((d+e (x^2)))^q)==((d^q)/(c ((Cos[ArcTan[c x]])^(2 (q+1)))))(∂_x)ArcTan[c x]

Rule: If  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0), then

∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  ((d^q)/c) Subst[∫((((a+b x))^p)/((Cos[x])^(2 (q+1))))dx,x,ArcTan[c x]]

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  d^q/c*Subst[Int[(a+b*x)^p/Cos[x]^(2*(q+1)),x],x,ArcTan[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && ILtQ[2*(q+1),0] && (IntegerQ[q] || GtQ[d,0])

2:  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0)

Derivation: Piecewise constant extraction

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0), then

∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  (((d^(q+(1/2)))(Sqrt[1+(c^2)(x^2)]))/(Sqrt[d+e (x^2)])) ∫(((1+(c^2)(x^2)))^q)(((a+b ArcTan[c x]))^p)dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  d^(q+1/2)*Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]*Int[(1+c^2*x^2)^q*(a+b*ArcTan[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && ILtQ[2*(q+1),0] && Not[IntegerQ[q] || GtQ[d,0]]

2.  ∫(((d+e (x^2)))^q) (((a+b ArcCot[c x]))^p)dx  when  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])

1:  ∫(((d+e (x^2)))^q) (((a+b ArcCot[c x]))^p)dx  when  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∈ℤ

Derivation: Integration by substitution

Basis: If  e==(c^2) d ∧ q∈ℤ, then (((d+e (x^2)))^q)==-((d^q)/(c ((Sin[ArcCot[c x]])^(2 (q+1)))))(∂_x)ArcCot[c x]

Rule: If  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∈ℤ, then

∫(((d+e (x^2)))^q) (((a+b ArcCot[c x]))^p)dx  ⟶  -((d^q)/c) Subst[∫((((a+b x))^p)/((Sin[x])^(2 (q+1))))dx,x,ArcCot[c x]]

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  -d^q/c*Subst[Int[(a+b*x)^p/Sin[x]^(2*(q+1)),x],x,ArcCot[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && ILtQ[2*(q+1),0] && IntegerQ[q]

2:  ∫(((d+e (x^2)))^q)(((a+b ArcCot[c x]))^p)dx  when  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∉ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((x (Sqrt[((1+(c^2)(x^2))/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))==0

Basis: If  2 (q+1)∈ℤ ∧ q∉ℤ, then x(Sqrt[1+(1/((c^2) (x^2)))])(((1+(c^2)(x^2)))^(q-(1/2)))==-(1/((c^2)((Sin[ArcCot[c x]])^(2(q+1)))))(∂_x)ArcCot[c x]

Rule: If  e==(c^2) d ∧ 2 (q+1)∈(SuperMinus[ℤ])∧ q∉ℤ, then

∫(((d+e (x^2)))^q)(((a+b ArcCot[c x]))^p)dx  ⟶  (((c^2)(d^(q+(1/2)))x (Sqrt[((1+(c^2)(x^2))/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)])) ∫x(Sqrt[1+(1/((c^2) (x^2)))])(((1+(c^2)(x^2)))^(q-(1/2)))(((a+b ArcCot[c x]))^p)dx
  ⟶  -(((d^(q+(1/2)))x (Sqrt[((1+(c^2)(x^2))/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)])) Subst[∫((((a+b x))^p)/((Sin[x])^(2 (q+1))))dx,x,ArcCot[c x]]

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  -d^(q+1/2)*x*Sqrt[(1+c^2*x^2)/(c^2*x^2)]/Sqrt[d+e*x^2]*Subst[Int[(a+b*x)^p/Sin[x]^(2*(q+1)),x],x,ArcCot[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && ILtQ[2*(q+1),0] && Not[IntegerQ[q]]

2.  ∫((a+b ArcTan[c x])/(d+e (x^2)))dx

1:  ∫((ArcTan[c x])/(d+e (x^2)))dx

Derivation: Algebraic expansion

Basis: ArcTan[z]==(1/2) i Log[1-i z]-(1/2) i Log[1+i z]

Basis: ArcCot[z]==(1/2) i Log[1-(i/z)]-(1/2) i Log[1+(i/z)]

Rule:

∫((ArcTan[c x])/(d+e (x^2)))dx  ⟶  (i/2)∫((Log[1-i c x])/(d+e (x^2)))dx-(i/2)∫((Log[1+i c x])/(d+e (x^2)))dx

Program code:

Int[ArcTan[c_.*x_]/(d_.+e_.*x_^2),x_Symbol] :=
  I/2*Int[Log[1-I*c*x]/(d+e*x^2),x] - I/2*Int[Log[1+I*c*x]/(d+e*x^2),x] /;
FreeQ[{c,d,e},x]

Int[ArcCot[c_.*x_]/(d_.+e_.*x_^2),x_Symbol] :=
  I/2*Int[Log[1-I/(c*x)]/(d+e*x^2),x] - I/2*Int[Log[1+I/(c*x)]/(d+e*x^2),x] /;
FreeQ[{c,d,e},x]

2:  ∫((a+b ArcTan[c x])/(d+e (x^2)))dx

Derivation: Algebraic expansion

Rule:

∫((a+b ArcTan[c x])/(d+e (x^2)))dx  ⟶  a∫(1/(d+e (x^2)))dx+b∫((ArcTan[c x])/(d+e (x^2)))dx

Program code:

Int[(a_+b_.*ArcTan[c_.*x_])/(d_.+e_.*x_^2),x_Symbol] :=
  a*Int[1/(d+e*x^2),x] + b*Int[ArcTan[c*x]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x]

Int[(a_+b_.*ArcCot[c_.*x_])/(d_.+e_.*x_^2),x_Symbol] :=
  a*Int[1/(d+e*x^2),x] + b*Int[ArcCot[c*x]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x]

3:  ∫(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  q∈ℤ ∨ q+(1/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts

Note: If  q∈(SuperPlus[ℤ])∨ q+(1/2)∈(SuperMinus[ℤ]), then ∫(((d+e (x^2)))^q)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  q∈ℤ ∨ q+(1/2)∈(SuperMinus[ℤ]), let u=∫(((d+e (x^2)))^q)dx, then

∫(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  ⟶  u (a+b ArcTan[c x])-b c∫(u/(1+(c^2) (x^2)))dx

Program code:

Int[(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^q,x]},  
  Dist[a+b*ArcTan[c*x],u,x] - b*c*Int[u/(1+c^2*x^2),x]] /;
FreeQ[{a,b,c,d,e},x] && (IntegerQ[q] || ILtQ[q+1/2,0])

Int[(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^q,x]},  
  Dist[a+b*ArcCot[c*x],u,x] + b*c*Int[u/(1+c^2*x^2),x]] /;
FreeQ[{a,b,c,d,e},x] && (IntegerQ[q] || ILtQ[q+1/2,0])

4:  ∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  q∈ℤ ∧ p∈(SuperPlus[ℤ])

Rule: If  q∈ℤ ∧ p∈(SuperPlus[ℤ]), then

∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  ∫(((a+b ArcTan[c x]))^p) ExpandIntegrand[(((d+e (x^2)))^q),x]dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTan[c*x])^p,(d+e*x^2)^q,x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[q] && IGtQ[p,0]

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCot[c*x])^p,(d+e*x^2)^q,x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[q] && IGtQ[p,0]

6.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx

1.  ∫(((((f x))^m)(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx

1:  ∫(((((f x))^m)(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  p>0 ∧ m>1

Derivation: Algebraic expansion

Basis: ((x^2)/(d+e (x^2)))==(1/e)-(d/(e (d+e (x^2))))

Rule: If  p>0 ∧ m>1, then

∫(((((f x))^m)(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  ((f^2)/e)∫(((f x))^(m-2))(((a+b ArcTan[c x]))^p)dx-((d (f^2))/e)∫(((((f x))^(m-2))(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  f^2/e*Int[(f*x)^(m-2)*(a+b*ArcTan[c*x])^p,x] -
  d*f^2/e*Int[(f*x)^(m-2)*(a+b*ArcTan[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && GtQ[m,1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  f^2/e*Int[(f*x)^(m-2)*(a+b*ArcCot[c*x])^p,x] -
  d*f^2/e*Int[(f*x)^(m-2)*(a+b*ArcCot[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && GtQ[m,1]

2:  ∫(((((f x))^m)(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  p>0 ∧ m<-1

Derivation: Algebraic expansion

Basis: (1/(d+e (x^2)))==(1/d)-((e (x^2))/(d (d+e (x^2))))

Rule: If  p>0 ∧ m<-1, then

∫(((((f x))^m)(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  (1/d)∫(((f x))^m)(((a+b ArcTan[c x]))^p)dx-(e/(d (f^2)))∫(((((f x))^(m+2))(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcTan[c*x])^p,x] -
  e/(d*f^2)*Int[(f*x)^(m+2)*(a+b*ArcTan[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && LtQ[m,-1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/d*Int[(f*x)^m*(a+b*ArcCot[c*x])^p,x] -
  e/(d*f^2)*Int[(f*x)^(m+2)*(a+b*ArcCot[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,f},x] && GtQ[p,0] && LtQ[m,-1]

3.  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d

1.  ∫((x (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d

1:  ∫((x (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion and power rule for integration

Basis: If  e==(c^2) d, then (x/(d+e (x^2)))==-((i c)/(e (1+(c^2)(x^2))))-(1/(c d(i- c x)))

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ]), then

∫((x (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  -((i (((a+b ArcTan[c x]))^(p+1)))/(b e(p+1)))-(1/(c d))∫((((a+b ArcTan[c x]))^p)/(i- c x))dx

Program code:

Int[x_*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  -I*(a+b*ArcTan[c*x])^(p+1)/(b*e*(p+1)) - 
  1/(c*d)*Int[(a+b*ArcTan[c*x])^p/(I-c*x),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0]

Int[x_*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  I*(a+b*ArcCot[c*x])^(p+1)/(b*e*(p+1)) - 
  1/(c*d)*Int[(a+b*ArcCot[c*x])^p/(I-c*x),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0]

2:  ∫((x (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d ∧ p∉(SuperPlus[ℤ])∧ p≠-1

Derivation: Integration by parts

Basis: If  e==(c^2) d, then ((((a+b ArcTan[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTan[c x]))^(p+1))/(b c d(p+1)))

Rule: If  e==(c^2) d ∧ p∉(SuperPlus[ℤ])∧ p≠-1, then

∫((x (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  ((x (((a+b ArcTan[c x]))^(p+1)))/(b c d(p+1)))-(1/(b c d(p+1)))∫(((a+b ArcTan[c x]))^(p+1))dx

Program code:

Int[x_*(a_.+b_.*ArcTan[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  x*(a+b*ArcTan[c*x])^(p+1)/(b*c*d*(p+1)) - 
  1/(b*c*d*(p+1))*Int[(a+b*ArcTan[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && Not[IGtQ[p,0]] && NeQ[p,-1]

Int[x_*(a_.+b_.*ArcCot[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  -x*(a+b*ArcCot[c*x])^(p+1)/(b*c*d*(p+1)) + 
  1/(b*c*d*(p+1))*Int[(a+b*ArcCot[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && Not[IGtQ[p,0]] && NeQ[p,-1]

2:  ∫((((a+b ArcTan[c x]))^p)/(x(d+e (x^2))))dx  when  e==(c^2) d ∧ p>0

Derivation: Algebraic expansion

Basis: If  e==(c^2) d, then (1/(x(d+e (x^2))))==-((i c)/(d+e (x^2)))+(i/(d x(i+c x)))

Rule: If  e==(c^2) d ∧ p>0, then

∫((((a+b ArcTan[c x]))^p)/(x(d+e (x^2))))dx  ⟶  -((i (((a+b ArcTan[c x]))^(p+1)))/(b d(p+1)))+(i/d)∫((((a+b ArcTan[c x]))^p)/(x(i+c x)))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./(x_*(d_+e_.*x_^2)),x_Symbol] :=
  -I*(a+b*ArcTan[c*x])^(p+1)/(b*d*(p+1)) +
  I/d*Int[(a+b*ArcTan[c*x])^p/(x*(I+c*x)),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./(x_*(d_+e_.*x_^2)),x_Symbol] :=
  I*(a+b*ArcCot[c*x])^(p+1)/(b*d*(p+1)) +
  I/d*Int[(a+b*ArcCot[c*x])^p/(x*(I+c*x)),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

3:  ∫(((((f x))^m)(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d ∧ p<-1

Derivation: Integration by parts

Basis: If  e==(c^2) d, then ((((a+b ArcTan[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTan[c x]))^(p+1))/(b c d (p+1)))

Rule: If  e==(c^2) d ∧ p<-1, then

∫(((((f x))^m)(((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  (((((f x))^m)(((a+b ArcTan[c x]))^(p+1)))/(b c d(p+1)))-((f m)/(b c d(p+1)))∫(((f x))^(m-1))(((a+b ArcTan[c x]))^(p+1))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTan[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  (f*x)^m*(a+b*ArcTan[c*x])^(p+1)/(b*c*d*(p+1)) - 
  f*m/(b*c*d*(p+1))*Int[(f*x)^(m-1)*(a+b*ArcTan[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && LtQ[p,-1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCot[c_.*x_])^p_/(d_+e_.*x_^2),x_Symbol] :=
  -(f*x)^m*(a+b*ArcCot[c*x])^(p+1)/(b*c*d*(p+1)) + 
  f*m/(b*c*d*(p+1))*Int[(f*x)^(m-1)*(a+b*ArcCot[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && LtQ[p,-1]

4:  ∫(((x^m)(a+b ArcTan[c x]))/(d+e (x^2)))dx  when  m∈ℤ ∧ ¬(m==1 ∧ a≠0)

Derivation: Algebraic expansion

Rule: If  m∈ℤ ∧ ¬(m==1 ∧ a≠0), then

∫(((x^m)(a+b ArcTan[c x]))/(d+e (x^2)))dx  ⟶  ∫(a+b ArcTan[c x])ExpandIntegrand[((x^m)/(d+e (x^2))),x]dx

Program code:

Int[x_^m_.*(a_.+b_.*ArcTan[c_.*x_])/(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTan[c*x]),x^m/(d+e*x^2),x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[m] && Not[EqQ[m,1] && NeQ[a,0]]

Int[x_^m_.*(a_.+b_.*ArcCot[c_.*x_])/(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCot[c*x]),x^m/(d+e*x^2),x],x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[m] && Not[EqQ[m,1] && NeQ[a,0]]

2.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d

1.  ∫x(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d

1:  ∫x (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ p>0 ∧ q≠-1

Derivation: Integration by parts

Rule: If  e==(c^2) d ∧ p>0 ∧ q≠-1, then

∫x (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  (((((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p))/(2 e(q+1)))-((b p)/(2 c(q+1)))∫(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p-1))dx

Program code:

Int[x_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p/(2*e*(q+1)) - 
  b*p/(2*c*(q+1))*Int[(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,q},x] && EqQ[e,c^2*d] && GtQ[p,0] && NeQ[q,-1]

Int[x_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p/(2*e*(q+1)) +
  b*p/(2*c*(q+1))*Int[(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,q},x] && EqQ[e,c^2*d] && GtQ[p,0] && NeQ[q,-1]

2:  ∫((x (((a+b ArcTan[c x]))^p))/(((d+e (x^2)))^2))dx  when  e==(c^2) d ∧ p<-1 ∧ p≠-2

Rule: If  e==(c^2) d ∧ p<-1 ∧ p≠-2, then

∫((x (((a+b ArcTan[c x]))^p))/(((d+e (x^2)))^2))dx  ⟶  ((x (((a+b ArcTan[c x]))^(p+1)))/(b c d (p+1) (d+e (x^2))))-(((1-(c^2) (x^2)) (((a+b ArcTan[c x]))^(p+2)))/((b^2)e (p+1) (p+2) (d+e (x^2))))-(4/((b^2)(p+1)(p+2)))∫((x (((a+b ArcTan[c x]))^(p+2)))/(((d+e (x^2)))^2))dx

Program code:

Int[x_*(a_.+b_.*ArcTan[c_.*x_])^p_/(d_+e_.*x_^2)^2,x_Symbol] :=
  x*(a+b*ArcTan[c*x])^(p+1)/(b*c*d*(p+1)*(d+e*x^2)) -
  (1-c^2*x^2)*(a+b*ArcTan[c*x])^(p+2)/(b^2*e*(p+1)*(p+2)*(d+e*x^2)) -
  4/(b^2*(p+1)*(p+2))*Int[x*(a+b*ArcTan[c*x])^(p+2)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[p,-1] && NeQ[p,-2]

Int[x_*(a_.+b_.*ArcCot[c_.*x_])^p_/(d_+e_.*x_^2)^2,x_Symbol] :=
  -x*(a+b*ArcCot[c*x])^(p+1)/(b*c*d*(p+1)*(d+e*x^2)) -
  (1-c^2*x^2)*(a+b*ArcCot[c*x])^(p+2)/(b^2*e*(p+1)*(p+2)*(d+e*x^2)) -
  4/(b^2*(p+1)*(p+2))*Int[x*(a+b*ArcCot[c*x])^(p+2)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[p,-1] && NeQ[p,-2]

2.  ∫(x^2)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d

1:  ∫(x^2)(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  e==(c^2) d ∧ q<-1

Rule: If  q==-(5/2), then better to use rule for when m+2q+3==0.

Rule: If  e==(c^2) d ∧ q<-1, then

∫(x^2)(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  ⟶  -((b(((d+e (x^2)))^(q+1)))/(4 (c^3) d(((q+1))^2)))+((x(((d+e (x^2)))^(q+1)) (a+b ArcTan[c x]))/(2 (c^2) d(q+1)))-(1/(2 (c^2) d (q+1)))∫(((d+e (x^2)))^(q+1)) (a+b ArcTan[c x])dx

Program code:

Int[x_^2*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  -b*(d+e*x^2)^(q+1)/(4*c^3*d*(q+1)^2) + 
  x*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])/(2*c^2*d*(q+1)) - 
  1/(2*c^2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && NeQ[q,-5/2]

Int[x_^2*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  b*(d+e*x^2)^(q+1)/(4*c^3*d*(q+1)^2) + 
  x*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])/(2*c^2*d*(q+1)) - 
  1/(2*c^2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && LtQ[q,-1] && NeQ[q,-5/2]

2:  ∫(((x^2) (((a+b ArcTan[c x]))^p))/(((d+e (x^2)))^2))dx  when  e==(c^2) d ∧ p>0

Rule: If  e==(c^2) d ∧ p>0, then

∫(((x^2) (((a+b ArcTan[c x]))^p))/(((d+e (x^2)))^2))dx  ⟶  ((((a+b ArcTan[c x]))^(p+1))/(2b (c^3) (d^2)(p+1)))-((x (((a+b ArcTan[c x]))^p))/(2 (c^2) d (d+e (x^2))))+((b p)/(2c))∫((x (((a+b ArcTan[c x]))^(p-1)))/(((d+e (x^2)))^2))dx

Program code:

Int[x_^2*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  (a+b*ArcTan[c*x])^(p+1)/(2*b*c^3*d^2*(p+1)) - 
  x*(a+b*ArcTan[c*x])^p/(2*c^2*d*(d+e*x^2)) + 
  b*p/(2*c)*Int[x*(a+b*ArcTan[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

Int[x_^2*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  -(a+b*ArcCot[c*x])^(p+1)/(2*b*c^3*d^2*(p+1)) - 
  x*(a+b*ArcCot[c*x])^p/(2*c^2*d*(d+e*x^2)) - 
  b*p/(2*c)*Int[x*(a+b*ArcCot[c*x])^(p-1)/(d+e*x^2)^2,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

3.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m+2q+2==0

1.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m+2q+2==0 ∧ q<-1 ∧ p≥1

1:  ∫(((f x))^m) (((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  e==(c^2) d ∧ m+2q+2==0 ∧ q<-1

Rule: If  e==(c^2) d ∧ m+2q+2==0 ∧ q<-1, then

∫(((f x))^m) (((d+e (x^2)))^q) (a+b ArcTan[c x])dx ⟶  
((b (((f x))^m) (((d+e (x^2)))^(q+1)))/(c d (m^2)))-((f (((f x))^(m-1)) (((d+e (x^2)))^(q+1)) (a+b ArcTan[c x]))/((c^2) d m))+(((f^2) (m-1))/((c^2) d m))∫(((f x))^(m-2)) (((d+e (x^2)))^(q+1)) (a+b ArcTan[c x])dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  b*(f*x)^m*(d+e*x^2)^(q+1)/(c*d*m^2) - 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])/(c^2*d*m) + 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && EqQ[m+2*q+2,0] && LtQ[q,-1]

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  -b*(f*x)^m*(d+e*x^2)^(q+1)/(c*d*m^2) - 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])/(c^2*d*m) + 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x]),x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && EqQ[m+2*q+2,0] && LtQ[q,-1]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m+2q+2==0 ∧ q<-1 ∧ p>1

Rule: If  e==(c^2) d ∧ m+2q+2==0 ∧ q<-1 ∧ p>1, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx ⟶  

((b p (((f x))^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^(p-1)))/(c d (m^2)))-((f (((f x))^(m-1)) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p))/((c^2) d m))-
(((b^2)p(p-1))/(m^2))∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p-2))dx+(((f^2) (m-1))/((c^2) d m))∫(((f x))^(m-2)) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p)dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_,x_Symbol] :=
  b*p*(f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^(p-1)/(c*d*m^2) - 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p/(c^2*d*m) - 
  b^2*p*(p-1)/m^2*Int[(f*x)^m*(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p-2),x] + 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && EqQ[m+2*q+2,0] && LtQ[q,-1] && GtQ[p,1]

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_,x_Symbol] :=
  -b*p*(f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^(p-1)/(c*d*m^2) - 
  f*(f*x)^(m-1)*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p/(c^2*d*m) - 
  b^2*p*(p-1)/m^2*Int[(f*x)^m*(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p-2),x] + 
  f^2*(m-1)/(c^2*d*m)*Int[(f*x)^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && EqQ[m+2*q+2,0] && LtQ[q,-1] && GtQ[p,1]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m+2q+2==0 ∧ p<-1

Derivation: Integration by parts

Basis: If  e==(c^2) d, then ((((a+b ArcTan[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTan[c x]))^(p+1))/(b c d (p+1)))

Basis: If  m+2q+2==0, then (∂_x)((x^m) (((d+e (x^2)))^(q+1)))==c m (x^(m-1)) (((d+e (x^2)))^q)

Rule: If  e==(c^2) d ∧ m+2q+2==0 ∧ p<-1, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx ⟶  (((((f x))^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^(p+1)))/(b c d(p+1)))-((f m)/(b c (p+1)))∫(((f x))^(m-1)) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_,x_Symbol] :=
  (f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^(p+1)/(b*c*d*(p+1)) - 
  f*m/(b*c*(p+1))*Int[(f*x)^(m-1)*(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[e,c^2*d] && EqQ[m+2*q+2,0] && LtQ[p,-1]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_,x_Symbol] :=
  -(f*x)^m*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^(p+1)/(b*c*d*(p+1)) + 
  f*m/(b*c*(p+1))*Int[(f*x)^(m-1)*(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[e,c^2*d] && EqQ[m+2*q+2,0] && LtQ[p,-1]

4:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m+2q+3==0 ∧ p>0 ∧ m≠-1

Derivation: Integration by parts

Basis: If  m+2q+3==0, then (x^m) (((d+e (x^2)))^q)==(∂_x)(((x^(m+1)) (((d+e (x^2)))^(q+1)))/(d (m+1)))

Rule: If  e==(c^2) d ∧ m+2q+3==0 ∧ p>0 ∧ m≠-1, then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx ⟶  (((((f x))^(m+1)) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p))/(d f (m+1)))-((b c p)/(f (m+1)))∫(((f x))^(m+1)) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p-1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p/(d*f*(m+1)) - 
  b*c*p/(f*(m+1))*Int[(f*x)^(m+1)*(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[e,c^2*d] && EqQ[m+2*q+3,0] && GtQ[p,0] && NeQ[m,-1]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p/(d*f*(m+1)) + 
  b*c*p/(f*(m+1))*Int[(f*x)^(m+1)*(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p-1),x] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && EqQ[e,c^2*d] && EqQ[m+2*q+3,0] && GtQ[p,0] && NeQ[m,-1]

5.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q>0

1:  ∫(((f x))^m) (Sqrt[d+e (x^2)]) (a+b ArcTan[c x])dx  when  e==(c^2) d ∧ m≠-2

Rule: If  e==(c^2) d ∧ m≠-2, then

∫(((f x))^m) (Sqrt[d+e (x^2)]) (a+b ArcTan[c x])dx  ⟶  (((((f x))^(m+1)) (Sqrt[d+e (x^2)]) (a+b ArcTan[c x]))/(f (m+2)))-((b c d)/(f (m+2)))∫((((f x))^(m+1))/(Sqrt[d+e (x^2)]))dx+(d/(m+2))∫(((((f x))^m) (a+b ArcTan[c x]))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcTan[c*x])/(f*(m+2)) - 
  b*c*d/(f*(m+2))*Int[(f*x)^(m+1)/Sqrt[d+e*x^2],x] + 
  d/(m+2)*Int[(f*x)^m*(a+b*ArcTan[c*x])/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && NeQ[m,-2]

Int[(f_.*x_)^m_*Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcCot[c*x])/(f*(m+2)) + 
  b*c*d/(f*(m+2))*Int[(f*x)^(m+1)/Sqrt[d+e*x^2],x] + 
  d/(m+2)*Int[(f*x)^m*(a+b*ArcCot[c*x])/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && NeQ[m,-2]

2:  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ q-1∈(SuperPlus[ℤ])

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ q-1∈(SuperPlus[ℤ]), then

∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  ∫ExpandIntegrand[(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p),x]dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q*(a+b*ArcTan[c*x])^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && IGtQ[p,0] && IGtQ[q,1] && (EqQ[p,1] || IntegerQ[m])

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(f*x)^m*(d+e*x^2)^q*(a+b*ArcCot[c*x])^p,x],x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && IGtQ[p,0] && IGtQ[q,1] && (EqQ[p,1] || IntegerQ[m])

3:  ∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q>0 ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: If  e==(c^2) d, then (((d+e (x^2)))^q)==d(((d+e (x^2)))^(q-1))+(c^2) d (x^2) (((d+e (x^2)))^(q-1))

Rule: If  e==(c^2) d ∧ q>0 ∧ p∈(SuperPlus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  d ∫(((f x))^m) (((d+e (x^2)))^(q-1)) (((a+b ArcTan[c x]))^p)dx+(((c^2) d)/(f^2))∫(((f x))^(m+2)) (((d+e (x^2)))^(q-1)) (((a+b ArcTan[c x]))^p)dx

Program code:

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  d*Int[(f*x)^m*(d+e*x^2)^(q-1)*(a+b*ArcTan[c*x])^p,x] + 
  c^2*d/f^2*Int[(f*x)^(m+2)*(d+e*x^2)^(q-1)*(a+b*ArcTan[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && GtQ[q,0] && IGtQ[p,0] && (RationalQ[m] || EqQ[p,1] && IntegerQ[q])

Int[(f_.*x_)^m_*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  d*Int[(f*x)^m*(d+e*x^2)^(q-1)*(a+b*ArcCot[c*x])^p,x] + 
  c^2*d/f^2*Int[(f*x)^(m+2)*(d+e*x^2)^(q-1)*(a+b*ArcCot[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,f,m},x] && EqQ[e,c^2*d] && GtQ[q,0] && IGtQ[p,0] && (RationalQ[m] || EqQ[p,1] && IntegerQ[q])

6.  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<0

1.  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d

1:  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p>0 ∧ m>1

Rule: If  e==(c^2) d ∧ p>0 ∧ m>1, then

∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx  ⟶  
((f(((f x))^(m-1)) (Sqrt[d+e (x^2)]) (((a+b ArcTan[c x]))^p))/((c^2)d m))-((b f p)/(c m))∫ (((((f x))^(m-1))(((a+b ArcTan[c x]))^(p-1)))/(Sqrt[d+e (x^2)]))dx-(((f^2) (m-1))/((c^2) m))∫(((((f x))^(m-2)) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTan[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  f*(f*x)^(m-1)*Sqrt[d+e*x^2]*(a+b*ArcTan[c*x])^p/(c^2*d*m) - 
  b*f*p/(c*m)*Int[(f*x)^(m-1)*(a+b*ArcTan[c*x])^(p-1)/Sqrt[d+e*x^2],x] - 
  f^2*(m-1)/(c^2*m)*Int[(f*x)^(m-2)*(a+b*ArcTan[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[p,0] && GtQ[m,1]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCot[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  f*(f*x)^(m-1)*Sqrt[d+e*x^2]*(a+b*ArcCot[c*x])^p/(c^2*d*m) + 
  b*f*p/(c*m)*Int[(f*x)^(m-1)*(a+b*ArcCot[c*x])^(p-1)/Sqrt[d+e*x^2],x] - 
  f^2*(m-1)/(c^2*m)*Int[(f*x)^(m-2)*(a+b*ArcCot[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[p,0] && GtQ[m,1]

2.  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p>0 ∧ m≤-1

1.  ∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])

1.  ∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0

1:  ∫(((a+b ArcTan[c x]))/(x(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ d>0

Derivation: Integration by substitution, piecewise constant extraction and algebraic simplification!

Note: Although not essential, these rules returns antiderivatives free of complex exponentials of the form  (e^(ArcTan[c x])) and  i (e^(ArcCot[c x])).

Basis: If  e==(c^2) d ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==(1/(Sqrt[d])) Csc[ArcTan[c x]] (∂_x)ArcTan[c x]

Basis: If  e==(c^2) d ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==-(1/(Sqrt[d]))((Csc[ArcCot[c x]] Sec[ArcCot[c x]])/(Sqrt[((Csc[ArcCot[c x]])^2)])) (∂_x)ArcCot[c x]

Rule: If  e==(c^2) d ∧ d>0, then

∫(((a+b ArcTan[c x]))/(x(Sqrt[d+e (x^2)])))dx  ⟶  (1/(Sqrt[d]))Subst[∫(a+b x)Csc[x]dx,x,ArcTan[c x]]
  ⟶  -(2/(Sqrt[d])) (a+b ArcTan[c x]) ArcTanh[((Sqrt[1+i c x])/(Sqrt[1-i c x]))]+((i b)/(Sqrt[d]))PolyLog[2,-((Sqrt[1+i c x])/(Sqrt[1-i c x]))]-((i b)/(Sqrt[d])) PolyLog[2,((Sqrt[1+i c x])/(Sqrt[1-i c x]))]

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -2/Sqrt[d]*(a+b*ArcTan[c*x])*ArcTanh[Sqrt[1+I*c*x]/Sqrt[1-I*c*x]] + 
  I*b/Sqrt[d]*PolyLog[2,-Sqrt[1+I*c*x]/Sqrt[1-I*c*x]] - 
  I*b/Sqrt[d]*PolyLog[2,Sqrt[1+I*c*x]/Sqrt[1-I*c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[d,0]

Int[(a_.+b_.*ArcCot[c_.*x_])/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -2/Sqrt[d]*(a+b*ArcCot[c*x])*ArcTanh[Sqrt[1+I*c*x]/Sqrt[1-I*c*x]] - 
  I*b/Sqrt[d]*PolyLog[2,-Sqrt[1+I*c*x]/Sqrt[1-I*c*x]] + 
  I*b/Sqrt[d]*PolyLog[2,Sqrt[1+I*c*x]/Sqrt[1-I*c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[d,0]

2.  ∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0

1:  ∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution

Basis: If  e==(c^2) d ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==(1/(Sqrt[d])) Csc[ArcTan[c x]] (∂_x)ArcTan[c x]

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  ⟶  (1/(Sqrt[d]))Subst[∫(((a+b x))^p) Csc[x]dx,x,ArcTan[c x]]

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  1/Sqrt[d]*Subst[Int[(a+b*x)^p*Csc[x],x],x,ArcTan[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcCot[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  e==(c^2) d ∧ d>0, then (1/(x(Sqrt[d+e (x^2)])))==-(1/(Sqrt[d]))((Csc[ArcCot[c x]] Sec[ArcCot[c x]])/(Sqrt[((Csc[ArcCot[c x]])^2)])) (∂_x)ArcCot[c x]

Basis: (∂_x)((Csc[x])/(Sqrt[((Csc[x])^2)]))==0

Basis: ((Csc[ArcCot[c x]])/(Sqrt[((Csc[ArcCot[c x]])^2)]))==((c x(Sqrt[1+(1/((c^2) (x^2)))]))/(Sqrt[1+(c^2)(x^2)]))

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d>0, then

∫((((a+b ArcCot[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  ⟶  -(1/(Sqrt[d]))Subst[∫(((((a+b x))^p)Csc[x] Sec[x])/(Sqrt[((Csc[x])^2)]))dx,x,ArcCot[c x]]                                   
                         ⟶  -((c x(Sqrt[1+(1/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))Subst[∫(((a+b x))^p)Sec[x]dx,x,ArcCot[c x]]

Program code:

Int[(a_.+b_.*ArcCot[c_.*x_])^p_/(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -c*x*Sqrt[1+1/(c^2*x^2)]/Sqrt[d+e*x^2]*Subst[Int[(a+b*x)^p*Sec[x],x],x,ArcCot[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && GtQ[d,0]

2:  ∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d≯0

Derivation: Piecewise constant extraction

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d ∧ p∈(SuperPlus[ℤ])∧ d≯0, then

∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[d+e (x^2)])))dx  ⟶  ((Sqrt[1+(c^2)(x^2)])/(Sqrt[d+e (x^2)]))∫((((a+b ArcTan[c x]))^p)/(x(Sqrt[1+(c^2)(x^2)])))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcTan[c*x])^p/(x*Sqrt[1+c^2*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && Not[GtQ[d,0]]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./(x_*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]*Int[(a+b*ArcCot[c*x])^p/(x*Sqrt[1+c^2*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && Not[GtQ[d,0]]

2.  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p>0 ∧ m<-1

1:  ∫((((a+b ArcTan[c x]))^p)/((x^2)(Sqrt[d+e (x^2)])))dx  when  e==(c^2) d ∧ p>0

Derivation: Integration by parts

Basis: (1/((x^2) (Sqrt[d+e (x^2)])))==-(∂_x)((Sqrt[d+e (x^2)])/(d x))

Rule: If  e==(c^2) d ∧ p>0, then

∫((((a+b ArcTan[c x]))^p)/((x^2)(Sqrt[d+e (x^2)])))dx  ⟶  -(((Sqrt[d+e (x^2)]) (((a+b ArcTan[c x]))^p))/(d x))+b c p∫ ((((a+b ArcTan[c x]))^(p-1))/(x(Sqrt[d+e (x^2)])))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_./(x_^2*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -Sqrt[d+e*x^2]*(a+b*ArcTan[c*x])^p/(d*x) + 
  b*c*p*Int[(a+b*ArcTan[c*x])^(p-1)/(x*Sqrt[d+e*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_./(x_^2*Sqrt[d_+e_.*x_^2]),x_Symbol] :=
  -Sqrt[d+e*x^2]*(a+b*ArcCot[c*x])^p/(d*x) - 
  b*c*p*Int[(a+b*ArcCot[c*x])^(p-1)/(x*Sqrt[d+e*x^2]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && GtQ[p,0]

2:  ∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx  when  e==(c^2) d ∧ p>0 ∧ m<-1 ∧ m≠-2

Rule: If  e==(c^2) d ∧ p>0 ∧ m<-1 ∧ m≠-2, then

∫(((((f x))^m) (((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx  ⟶  
(((((f x))^(m+1)) (Sqrt[d+e (x^2)]) (((a+b ArcTan[c x]))^p))/(d f (m+1)))-((b c p)/(f (m+1)))∫ (((((f x))^(m+1))(((a+b ArcTan[c x]))^(p-1)))/(Sqrt[d+e (x^2)]))dx-(((c^2) (m+2))/( (f^2) (m+1)))∫(((((f x))^(m+2))(((a+b ArcTan[c x]))^p))/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(f_.*x_)^m_*(a_.+b_.*ArcTan[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcTan[c*x])^p/(d*f*(m+1)) - 
  b*c*p/(f*(m+1))*Int[(f*x)^(m+1)*(a+b*ArcTan[c*x])^(p-1)/Sqrt[d+e*x^2],x] - 
  c^2*(m+2)/(f^2*(m+1))*Int[(f*x)^(m+2)*(a+b*ArcTan[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[p,0] && LtQ[m,-1] && NeQ[m,-2]

Int[(f_.*x_)^m_*(a_.+b_.*ArcCot[c_.*x_])^p_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  (f*x)^(m+1)*Sqrt[d+e*x^2]*(a+b*ArcCot[c*x])^p/(d*f*(m+1)) + 
  b*c*p/(f*(m+1))*Int[(f*x)^(m+1)*(a+b*ArcCot[c*x])^(p-1)/Sqrt[d+e*x^2],x] - 
  c^2*(m+2)/(f^2*(m+1))*Int[(f*x)^(m+2)*(a+b*ArcCot[c*x])^p/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,f},x] && EqQ[e,c^2*d] && GtQ[p,0] && LtQ[m,-1] && NeQ[m,-2]

2.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ q<-1

1:  ∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m>1 ∧ p≠-1

Derivation: Algebraic expansion

Basis: ((x^2)/(d+e (x^2)))==(1/e)-(d/(e (d+e (x^2))))

Rule: If  e==(c^2) d ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m>1 ∧ p≠-1, then

∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  (1/e)∫(x^(m-2)) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p)dx-(d/e)∫(x^(m-2)) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  1/e*Int[x^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p,x] -
  d/e*Int[x^(m-2)*(d+e*x^2)^q*(a+b*ArcTan[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IntegersQ[p,2*q] && LtQ[q,-1] && IGtQ[m,1] && NeQ[p,-1]

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  1/e*Int[x^(m-2)*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p,x] -
  d/e*Int[x^(m-2)*(d+e*x^2)^q*(a+b*ArcCot[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IntegersQ[p,2*q] && LtQ[q,-1] && IGtQ[m,1] && NeQ[p,-1]

2:  ∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m<0 ∧ p≠-1

Derivation: Algebraic expansion

Basis: (1/(d+e (x^2)))==(1/d)-((e (x^2))/(d (d+e (x^2))))

Rule: If  e==(c^2) d ∧ (m|p|2q)∈ℤ ∧ q<-1 ∧ m<0 ∧ p≠-1, then

∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  (1/d)∫(x^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^p)dx-(e/d)∫(x^(m+2)) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx

Program code:

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  1/d*Int[x^m*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^p,x] -
  e/d*Int[x^(m+2)*(d+e*x^2)^q*(a+b*ArcTan[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IntegersQ[p,2*q] && LtQ[q,-1] && ILtQ[m,0] && NeQ[p,-1]

Int[x_^m_*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  1/d*Int[x^m*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^p,x] -
  e/d*Int[x^(m+2)*(d+e*x^2)^q*(a+b*ArcCot[c*x])^p,x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IntegersQ[p,2*q] && LtQ[q,-1] && ILtQ[m,0] && NeQ[p,-1]

3:  ∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m∈ℤ ∧ q<-1 ∧ p<-1 ∧ m+2q+2≠0

Derivation: Integration by parts

Rule: If  e==(c^2) d ∧ m∈ℤ ∧ q<-1 ∧ p<-1 ∧ m+2q+2≠0, then

∫(x^m) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx ⟶  
(((x^m) (((d+e (x^2)))^(q+1)) (((a+b ArcTan[c x]))^(p+1)))/(b c d(p+1)))-(m/(b c (p+1)))∫(x^(m-1)) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p+1))dx-((c (m+2q+2))/(b (p+1)))∫(x^(m+1)) (((d+e (x^2)))^q) (((a+b ArcTan[c x]))^(p+1))dx

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  x^m*(d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])^(p+1)/(b*c*d*(p+1)) - 
  m/(b*c*(p+1))*Int[x^(m-1)*(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p+1),x] - 
  c*(m+2*q+2)/(b*(p+1))*Int[x^(m+1)*(d+e*x^2)^q*(a+b*ArcTan[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,m},x] && EqQ[e,c^2*d] && IntegerQ[m] && LtQ[q,-1] && LtQ[p,-1] && NeQ[m+2*q+2,0]

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  -x^m*(d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])^(p+1)/(b*c*d*(p+1)) + 
  m/(b*c*(p+1))*Int[x^(m-1)*(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p+1),x] + 
  c*(m+2*q+2)/(b*(p+1))*Int[x^(m+1)*(d+e*x^2)^q*(a+b*ArcCot[c*x])^(p+1),x] /;
FreeQ[{a,b,c,d,e,m},x] && EqQ[e,c^2*d] && IntegerQ[m] && LtQ[q,-1] && LtQ[p,-1] && NeQ[m+2*q+2,0]

4.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])

1.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])

1:  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0)

Derivation: Integration by substitution

Basis: If  e==(c^2) d ∧ m∈ℤ ∧ m+2 q+1∈ℤ ∧ (q∈ℤ ∨ d>0), then (x^m)(((d+e (x^2)))^q)==(((d^q)((Sin[ArcTan[c x]])^m))/((c^(m+1))((Cos[ArcTan[c x]])^(m+2 (q+1)))))(∂_x)ArcTan[c x]

Rule: If  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ (q∈ℤ ∨ d>0), then

∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  ((d^q)/(c^(m+1))) Subst[∫(((((a+b x))^p)((Sin[x])^m))/((Cos[x])^(m+2 (q+1))))dx,x,ArcTan[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  d^q/c^(m+1)*Subst[Int[(a+b*x)^p*Sin[x]^m/Cos[x]^(m+2*(q+1)),x],x,ArcTan[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && (IntegerQ[q] || GtQ[d,0])

2:  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  e==(c^2) d ∧ m∈(SuperPlus[ℤ]) ∧ m+2 q+1∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0)

Derivation: Piecewise constant extraction

Basis: If  e==(c^2) d, then (∂_x)((Sqrt[1+(c^2)(x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  e==(c^2) d ∧ m∈(SuperPlus[ℤ]) ∧ m+2 q+1∈(SuperMinus[ℤ])∧ ¬(q∈ℤ ∨ d>0), then

∫(x^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  (((d^(q+(1/2)))(Sqrt[1+(c^2)(x^2)]))/(Sqrt[d+e (x^2)])) ∫(x^m)(((1+(c^2)(x^2)))^q)(((a+b ArcTan[c x]))^p)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  d^(q+1/2)*Sqrt[1+c^2*x^2]/Sqrt[d+e*x^2]*Int[x^m*(1+c^2*x^2)^q*(a+b*ArcTan[c*x])^p,x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && Not[IntegerQ[q] || GtQ[d,0]]

2.  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcCot[c x]))^p)dx  when  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])

1:  ∫(x^m)(((d+e (x^2)))^q) (((a+b ArcCot[c x]))^p)dx  when  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∈ℤ

Derivation: Integration by substitution

Basis: If  e==(c^2) d ∧ m∈ℤ ∧ q∈ℤ, then (x^m)(((d+e (x^2)))^q)==-(((d^q)((Cos[ArcCot[c x]])^m))/((c^(m+1))((Sin[ArcCot[c x]])^(m+2(q+1)))))(∂_x)ArcCot[c x]

Rule: If  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∈ℤ, then

∫(x^m)(((d+e (x^2)))^q) (((a+b ArcCot[c x]))^p)dx  ⟶  -((d^q)/(c^(m+1))) Subst[∫(((((a+b x))^p)((Cos[x])^m))/((Sin[x])^(m+2 (q+1))))dx,x,ArcCot[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  -d^q/c^(m+1)*Subst[Int[(a+b*x)^p*Cos[x]^m/Sin[x]^(m+2*(q+1)),x],x,ArcCot[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && IntegerQ[q]

2:  ∫(x^m)(((d+e (x^2)))^q)(((a+b ArcCot[c x]))^p)dx  when  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∉ℤ

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  e==(c^2) d, then (∂_x)((x (Sqrt[((1+(c^2)(x^2))/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)]))==0

Basis: If  m∈ℤ ∧ m+2 q+1∈ℤ ∧ q∉ℤ, then (x^(m+1))(Sqrt[1+(1/((c^2) (x^2)))])(((1+(c^2)(x^2)))^(q-(1/2)))==-(((Cos[ArcCot[c x]])^m)/((c^(m+2))((Sin[ArcCot[c x]])^(m+2(q+1)))))(∂_x)ArcCot[c x]

Rule: If  e==(c^2) d ∧ m∈(SuperPlus[ℤ])∧ m+2 q+1∈(SuperMinus[ℤ])∧ q∉ℤ, then

∫(x^m)(((d+e (x^2)))^q)(((a+b ArcCot[c x]))^p)dx  ⟶  (((c^2)(d^(q+(1/2)))x (Sqrt[((1+(c^2)(x^2))/((c^2) (x^2)))]))/(Sqrt[d+e (x^2)])) ∫(x^(m+1))(Sqrt[1+(1/((c^2) (x^2)))])(((1+(c^2)(x^2)))^(q-(1/2)))(((a+b ArcCot[c x]))^p)dx
  ⟶  -(((d^(q+(1/2)))x (Sqrt[((1+(c^2)(x^2))/((c^2) (x^2)))]))/((c^m)(Sqrt[d+e (x^2)]))) Subst[∫(((((a+b x))^p)((Cos[x])^m))/((Sin[x])^(m+2 (q+1))))dx,x,ArcCot[c x]]

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  -d^(q+1/2)*x*Sqrt[(1+c^2*x^2)/(c^2*x^2)]/(c^m*Sqrt[d+e*x^2])*Subst[Int[(a+b*x)^p*Cos[x]^m/Sin[x]^(m+2*(q+1)),x],x,ArcCot[c*x]] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[e,c^2*d] && IGtQ[m,0] && ILtQ[m+2*q+1,0] && Not[IntegerQ[q]]

3.  ∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

1:  ∫x(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  q≠-1

Derivation: Integration by parts

Basis: x(((d+e (x^2)))^q)==(∂_x)((((d+e (x^2)))^(q+1))/(2 e (q+1)))

Rule: If  q≠-1, then

∫x(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  ⟶  (((((d+e (x^2)))^(q+1))(a+b ArcTan[c x]))/(2 e (q+1)))-((b c)/(2 e (q+1)))∫((((d+e (x^2)))^(q+1))/(1+(c^2) (x^2)))dx

Program code:

Int[x_*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcTan[c*x])/(2*e*(q+1)) - 
  b*c/(2*e*(q+1))*Int[(d+e*x^2)^(q+1)/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[q,-1]

Int[x_*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(q+1)*(a+b*ArcCot[c*x])/(2*e*(q+1)) + 
  b*c/(2*e*(q+1))*Int[(d+e*x^2)^(q+1)/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,q},x] && NeQ[q,-1]

2:  ∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  when  (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

Derivation: Integration by parts

Note: If (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])),
	then ∫(((f x))^m)(((d+e (x^2)))^q)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  (q∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(q∈(SuperMinus[ℤ])∧ m+2q+3>0))∨(((m+2q+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])), let u=∫(((f x))^m)(((d+e (x^2)))^q)dx, then

∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  ⟶  u (a+b ArcTan[c x])-b c∫(u/(1+(c^2) (x^2)))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^q,x]},  
  Dist[a+b*ArcTan[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && (
  IGtQ[q,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*q+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[q,0] && GtQ[m+2*q+3,0]] || 
  ILtQ[(m+2*q+1)/2,0] && Not[ILtQ[(m-1)/2,0]] )

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^q,x]},  
  Dist[a+b*ArcCot[c*x],u,x] + b*c*Int[SimplifyIntegrand[u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,q},x] && (
  IGtQ[q,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*q+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[q,0] && GtQ[m+2*q+3,0]] || 
  ILtQ[(m+2*q+1)/2,0] && Not[ILtQ[(m-1)/2,0]] )

4:  ∫((x (((a+b ArcTan[c x]))^p))/(((d+e (x^2)))^2))dx  when  p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: (x/(((d+e (x^2)))^2))==(1/(4 (d^2) (Sqrt[-(e/d)]) (((1-(Sqrt[-(e/d)]) x))^2)))-(1/(4 (d^2) (Sqrt[-(e/d)]) (((1+(Sqrt[-(e/d)]) x))^2)))

Rule: If  p∈(SuperPlus[ℤ]), then

∫((x (((a+b ArcTan[c x]))^p))/(((d+e (x^2)))^2))dx  ⟶  (1/(4 (d^2) (Sqrt[-(e/d)]))) ∫((((a+b ArcTan[c x]))^p)/(((1-(Sqrt[-(e/d)]) x))^2))dx-(1/(4 (d^2) (Sqrt[-(e/d)]))) ∫((((a+b ArcTan[c x]))^p)/(((1+(Sqrt[-(e/d)]) x))^2))dx

Program code:

Int[x_*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcTan[c*x])^p/(1-Rt[-e/d,2]*x)^2,x] - 
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcTan[c*x])^p/(1+Rt[-e/d,2]*x)^2,x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0]

Int[x_*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2)^2,x_Symbol] :=
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcCot[c*x])^p/(1-Rt[-e/d,2]*x)^2,x] - 
  1/(4*d^2*Rt[-e/d,2])*Int[(a+b*ArcCot[c*x])^p/(1+Rt[-e/d,2]*x)^2,x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0]

5:  ∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  when  q∈ℤ ∧ p∈(SuperPlus[ℤ])∧ (p==1 ∨ m∈ℤ)

Derivation: Algebraic expansion

Rule: If  q∈ℤ ∧ p∈(SuperPlus[ℤ])∧ (p==1 ∨ m∈ℤ), then

∫(((f x))^m)(((d+e (x^2)))^q) (((a+b ArcTan[c x]))^p)dx  ⟶  ∫(((a+b ArcTan[c x]))^p)ExpandIntegrand[(((f x))^m)(((d+e (x^2)))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*ArcTan[c*x])^p,(f*x)^m*(d+e*x^2)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m},x] && IntegerQ[q] && IGtQ[p,0] && (EqQ[p,1] && GtQ[q,0] || IntegerQ[m])

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*ArcCot[c*x])^p,(f*x)^m*(d+e*x^2)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m},x] && IntegerQ[q] && IGtQ[p,0] && (EqQ[p,1] && GtQ[q,0] || IntegerQ[m])

6:  ∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTan[c x])dx

Derivation: Algebraic expansion

Rule:

∫(((f x))^m)(((d+e (x^2)))^q) (a+b ArcTan[c x])dx  ⟶  a∫(((f x))^m)(((d+e (x^2)))^q)dx+b∫(((f x))^m)(((d+e (x^2)))^q) ArcTan[c x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  a*Int[(f*x)^m*(d+e*x^2)^q,x] + b*Int[(f*x)^m*(d+e*x^2)^q*ArcTan[c*x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x]

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  a*Int[(f*x)^m*(d+e*x^2)^q,x] + b*Int[(f*x)^m*(d+e*x^2)^q*ArcCot[c*x],x] /;
FreeQ[{a,b,c,d,e,f,m,q},x]

7.  ∫((u (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d

1:  ∫(((((f+g x))^m) (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧  m∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧  m∈(SuperPlus[ℤ]), then

∫(((((f+g x))^m) (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  ∫((((a+b ArcTan[c x]))^p)/(d+e (x^2))) ExpandIntegrand[(((f+g x))^m),x]dx

Program code:

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcTan[c*x])^p/(d+e*x^2),(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[e,c^2*d] && IGtQ[m,0]

Int[(f_+g_.*x_)^m_.*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCot[c*x])^p/(d+e*x^2),(f+g*x)^m,x],x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[e,c^2*d] && IGtQ[m,0]

2.  ∫((ArcTanh[u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d

1:  ∫((ArcTanh[u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I+c x))))^2)

Derivation: Algebraic expansion

Basis: ArcTanh[z]==(1/2) Log[1+z]-(1/2) Log[1-z]

Basis: ArcCoth[z]==(1/2) Log[1+(1/z)]-(1/2) Log[1-(1/z)]

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I+c x))))^2), then

∫((ArcTanh[u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  (1/2) ∫((Log[1+u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx-(1/2) ∫((Log[1-u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[ArcTanh[u_]*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[1+u]*(a+b*ArcTan[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[1-u]*(a+b*ArcTan[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I+c*x))^2,0]

Int[ArcCoth[u_]*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[SimplifyIntegrand[1+1/u,x]]*(a+b*ArcCot[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[SimplifyIntegrand[1-1/u,x]]*(a+b*ArcCot[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I+c*x))^2,0]

2:  ∫((ArcTanh[u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I-c x))))^2)

Derivation: Algebraic expansion

Basis: ArcTanh[z]==(1/2) Log[1+z]-(1/2) Log[1-z]

Basis: ArcCoth[z]==(1/2) Log[1+(1/z)]-(1/2) Log[1-(1/z)]

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I-c x))))^2), then

∫((ArcTanh[u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  (1/2) ∫((Log[1+u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx-(1/2) ∫((Log[1-u](((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx

Program code:

Int[ArcTanh[u_]*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[1+u]*(a+b*ArcTan[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[1-u]*(a+b*ArcTan[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I-c*x))^2,0]

Int[ArcCoth[u_]*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  1/2*Int[Log[SimplifyIntegrand[1+1/u,x]]*(a+b*ArcCot[c*x])^p/(d+e*x^2),x] -
  1/2*Int[Log[SimplifyIntegrand[1-1/u,x]]*(a+b*ArcCot[c*x])^p/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I-c*x))^2,0]

3.  ∫(((((a+b ArcTan[c x]))^p) Log[u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d

1:  ∫(((((a+b ArcTan[c x]))^p) Log[f+g x])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (c^2) (f^2)+(g^2)==0

Derivation: Integration by parts

Basis: If  e==(c^2) d, then ((((a+b ArcTan[c x]))^p)/(d+e (x^2)))==(∂_x)((((a+b ArcTan[c x]))^(p+1))/(b c d (p+1)))

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (c^2) (f^2)+(g^2)==0, then

∫(((((a+b ArcTan[c x]))^p) Log[f+g x])/(d+e (x^2)))dx  ⟶  (( (((a+b ArcTan[c x]))^(p+1)) Log[f+g x])/(b c d (p+1)))-(g/(b c d (p+1)))∫((((a+b ArcTan[c x]))^(p+1))/(f+g x))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_.*Log[f_+g_.*x_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTan[c*x])^(p+1)*Log[f+g*x]/(b*c*d*(p+1)) - 
  g/(b*c*d*(p+1))*Int[(a+b*ArcTan[c*x])^(p+1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[c^2*f^2+g^2,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_.*Log[f_+g_.*x_]/(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcCot[c*x])^(p+1)*Log[f+g*x]/(b*c*d*(p+1)) - 
  g/(b*c*d*(p+1))*Int[(a+b*ArcCot[c*x])^(p+1)/(f+g*x),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[c^2*f^2+g^2,0]

2:  ∫(((((a+b ArcTan[c x]))^p) Log[u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (((1-u))^2)==(((1-((2I)/(I+c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (((1-u))^2)==(((1-((2I)/(I+c x))))^2), then

∫(((((a+b ArcTan[c x]))^p) Log[u])/(d+e (x^2)))dx  ⟶  (( i (((a+b ArcTan[c x]))^p) PolyLog[2,1-u])/(2c d))-((b p i)/2)∫(((((a+b ArcTan[c x]))^(p-1)) PolyLog[2,1-u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  I*(a+b*ArcTan[c*x])^p*PolyLog[2,1-u]/(2*c*d) -
  b*p*I/2*Int[(a+b*ArcTan[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[(1-u)^2-(1-2*I/(I+c*x))^2,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  I*(a+b*ArcCot[c*x])^p*PolyLog[2,1-u]/(2*c*d) +
  b*p*I/2*Int[(a+b*ArcCot[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[(1-u)^2-(1-2*I/(I+c*x))^2,0]

3:  ∫(((((a+b ArcTan[c x]))^p) Log[u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (((1-u))^2)==(((1-((2I)/(I-c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (((1-u))^2)==(((1-((2I)/(I-c x))))^2), then

∫(((((a+b ArcTan[c x]))^p) Log[u])/(d+e (x^2)))dx  ⟶  -((i (((a+b ArcTan[c x]))^p) PolyLog[2,1-u])/(2c d))+((b p i)/2) ∫(((((a+b ArcTan[c x]))^(p-1)) PolyLog[2,1-u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  -I*(a+b*ArcTan[c*x])^p*PolyLog[2,1-u]/(2*c*d) +
  b*p*I/2*Int[(a+b*ArcTan[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[(1-u)^2-(1-2*I/(I-c*x))^2,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_.*Log[u_]/(d_+e_.*x_^2),x_Symbol] :=
  -I*(a+b*ArcCot[c*x])^p*PolyLog[2,1-u]/(2*c*d) -
  b*p*I/2*Int[(a+b*ArcCot[c*x])^(p-1)*PolyLog[2,1-u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[(1-u)^2-(1-2*I/(I-c*x))^2,0]

4.  ∫(((((a+b ArcTan[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d

1:  ∫(((((a+b ArcTan[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I+c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I+c x))))^2), then

∫(((((a+b ArcTan[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  ⟶   -((i (((a+b ArcTan[c x]))^p) PolyLog[k+1,u])/(2c d))+((b p i)/2) ∫(((((a+b ArcTan[c x]))^(p-1)) PolyLog[k+1,u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  -I*(a+b*ArcTan[c*x])^p*PolyLog[k+1,u]/(2*c*d) +
  b*p*I/2*Int[(a+b*ArcTan[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I+c*x))^2,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  -I*(a+b*ArcCot[c*x])^p*PolyLog[k+1,u]/(2*c*d) -
  b*p*I/2*Int[(a+b*ArcCot[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I+c*x))^2,0]

2:  ∫(((((a+b ArcTan[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  when  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I-c x))))^2)

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ e==(c^2) d ∧ (u^2)==(((1-((2I)/(I-c x))))^2), then

∫(((((a+b ArcTan[c x]))^p) PolyLog[k,u])/(d+e (x^2)))dx  ⟶  ((i (((a+b ArcTan[c x]))^p) PolyLog[k+1,u])/(2c d))-((b p i)/2) ∫(((((a+b ArcTan[c x]))^(p-1)) PolyLog[k+1,u])/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcTan[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  I*(a+b*ArcTan[c*x])^p*PolyLog[k+1,u]/(2*c*d) -
  b*p*I/2*Int[(a+b*ArcTan[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I-c*x))^2,0]

Int[(a_.+b_.*ArcCot[c_.*x_])^p_.*PolyLog[k_,u_]/(d_+e_.*x_^2),x_Symbol] :=
  I*(a+b*ArcCot[c*x])^p*PolyLog[k+1,u]/(2*c*d) +
  b*p*I/2*Int[(a+b*ArcCot[c*x])^(p-1)*PolyLog[k+1,u]/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e,k},x] && IGtQ[p,0] && EqQ[e,c^2*d] && EqQ[u^2-(1-2*I/(I-c*x))^2,0]

5.  ∫(((((a+b ArcCot[c x]))^q) (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d

1:  ∫(1/((d+e (x^2)) (a+b ArcCot[c x]) (a+b ArcTan[c x])))dx  when  e==(c^2) d

Rule: If  e==(c^2) d, then

∫(1/((d+e (x^2)) (a+b ArcCot[c x]) (a+b ArcTan[c x])))dx  ⟶  ((-Log[a+b ArcCot[c x]]+Log[a+b ArcTan[c x]])/(b c d (2 a+b ArcCot[c x]+b ArcTan[c x])))

Program code:

Int[1/((d_+e_.*x_^2)*(a_.+b_.*ArcCot[c_.*x_])*(a_.+b_.*ArcTan[c_.*x_])),x_Symbol] :=
  (-Log[a+b*ArcCot[c*x]]+Log[a+b*ArcTan[c*x]])/(b*c*d*(2*a+b*ArcCot[c*x]+b*ArcTan[c*x])) /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d]

2:  ∫(((((a+b ArcCot[c x]))^q) (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  when  e==(c^2) d ∧ (p|q)∈ℤ ∧ 0<p≤q

Derivation: Integration by parts

Rule: If  e==(c^2) d ∧ (p|q)∈ℤ ∧ 0<p≤q, then

∫(((((a+b ArcCot[c x]))^q) (((a+b ArcTan[c x]))^p))/(d+e (x^2)))dx  ⟶  -(((((a+b ArcCot[c x]))^(q+1)) (((a+b ArcTan[c x]))^p))/(b c d(q+1)))+(p/(q+1))∫(((((a+b ArcCot[c x]))^(q+1)) (((a+b ArcTan[c x]))^(p-1)))/(d+e (x^2)))dx

Program code:

Int[(a_.+b_.*ArcCot[c_.*x_])^q_.*(a_.+b_.*ArcTan[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  -(a+b*ArcCot[c*x])^(q+1)*(a+b*ArcTan[c*x])^p/(b*c*d*(q+1)) +
  p/(q+1)*Int[(a+b*ArcCot[c*x])^(q+1)*(a+b*ArcTan[c*x])^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && IGeQ[q,p]

Int[(a_.+b_.*ArcTan[c_.*x_])^q_.*(a_.+b_.*ArcCot[c_.*x_])^p_./(d_+e_.*x_^2),x_Symbol] :=
  (a+b*ArcTan[c*x])^(q+1)*(a+b*ArcCot[c*x])^p/(b*c*d*(q+1)) +
  p/(q+1)*Int[(a+b*ArcTan[c*x])^(q+1)*(a+b*ArcCot[c*x])^(p-1)/(d+e*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[e,c^2*d] && IGtQ[p,0] && IGeQ[q,p]

8:  ∫((ArcTan[a x])/(c+d (x^n)))dx  when  n∈ℤ ∧ ¬(n==2∧d==(a^2) c)

Derivation: Algebraic expansion

Basis: ArcTan[z]==(1/2) i Log[1-i z]-(1/2) i Log[1+i z]

Basis: ArcCot[z]==(1/2) i Log[1-(i/z)]-(1/2) i Log[1+(i/z)]

Rule: If  n∈ℤ ∧ ¬(n==2∧d==(a^2) c), then

∫((ArcTan[a x])/(c+d (x^n)))dx  ⟶  (i/2)∫((Log[1-i a x])/(c+d (x^n)))dx-(i/2)∫((Log[1+i a x])/(c+d (x^n)))dx

Program code:

Int[ArcTan[a_.*x_]/(c_+d_.*x_^n_.),x_Symbol] :=
  I/2*Int[Log[1-I*a*x]/(c+d*x^n),x] -
  I/2*Int[Log[1+I*a*x]/(c+d*x^n),x] /;
FreeQ[{a,c,d},x] && IntegerQ[n] && Not[EqQ[n,2] && EqQ[d,a^2*c]]

Int[ArcCot[a_.*x_]/(c_+d_.*x_^n_.),x_Symbol] :=
  I/2*Int[Log[1-I/(a*x)]/(c+d*x^n),x] -
  I/2*Int[Log[1+I/(a*x)]/(c+d*x^n),x] /;
FreeQ[{a,c,d},x] && IntegerQ[n] && Not[EqQ[n,2] && EqQ[d,a^2*c]]

9.  ∫((Log[d (x^m)] (a+b ArcTan[c (x^n)]))/x)dx

1:  ∫((Log[d (x^m)] ArcTan[c (x^n)])/x)dx

Derivation: Algebraic expansion

Basis: ArcTan[c (x^n)]==(i/2) Log[1-i c (x^n)]-(i/2) Log[1+i c (x^n)]

Rule:

∫((Log[d (x^m)] ArcTan[c (x^n)])/x)dx  ⟶  (i/2) ∫((Log[d (x^m)] Log[1-i c (x^n)])/x)dx-(i/2) ∫((Log[d (x^m)] Log[1+i c (x^n)])/x)dx

Program code:

Int[Log[d_.*x_^m_.]*ArcTan[c_.*x_^n_.]/x_,x_Symbol] :=
  I/2*Int[Log[d*x^m]*Log[1-I*c*x^n]/x,x] - I/2*Int[Log[d*x^m]*Log[1+I*c*x^n]/x,x] /;
FreeQ[{c,d,m,n},x]

Int[Log[d_.*x_^m_.]*ArcCot[c_.*x_^n_.]/x_,x_Symbol] :=
  I/2*Int[Log[d*x^m]*Log[1-I/(c*x^n)]/x,x] - I/2*Int[Log[d*x^m]*Log[1+I/(c*x^n)]/x,x] /;
FreeQ[{c,d,m,n},x]

2:  ∫((Log[d (x^m)] (a+b ArcTan[c (x^n)]))/x)dx

Derivation: Algebraic expansion

Rule:

∫((Log[d (x^m)] (a+b ArcTan[c (x^n)]))/x)dx  ⟶  a ∫((Log[d (x^m)])/x)dx+b ∫((Log[d (x^m)] ArcTan[c (x^n)])/x)dx

Program code:

Int[Log[d_.*x_^m_.]*(a_+b_.*ArcTan[c_.*x_^n_.])/x_,x_Symbol] :=
  a*Int[Log[d*x^m]/x,x] + b*Int[(Log[d*x^m]*ArcTan[c*x^n])/x,x] /;
FreeQ[{a,b,c,d,m,n},x]

Int[Log[d_.*x_^m_.]*(a_+b_.*ArcCot[c_.*x_^n_.])/x_,x_Symbol] :=
  a*Int[Log[d*x^m]/x,x] + b*Int[(Log[d*x^m]*ArcCot[c*x^n])/x,x] /;
FreeQ[{a,b,c,d,m,n},x]

10.  ∫u(d+e Log[f+g (x^2)])(((a+b ArcTan[c x]))^p)dx

1:  ∫(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx

Derivation: Integration by parts

Rule:

∫(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx  ⟶  
x(d+e Log[f+g (x^2)])(a+b ArcTan[c x])-2e g∫(((x^2)(a+b ArcTan[c x]))/(f+g (x^2)))dx-b c∫((x(d+e Log[f+g (x^2)]))/(1+(c^2) (x^2)))dx

Program code:

Int[(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  x*(d+e*Log[f+g*x^2])*(a+b*ArcTan[c*x]) - 
  2*e*g*Int[x^2*(a+b*ArcTan[c*x])/(f+g*x^2),x] - 
  b*c*Int[x*(d+e*Log[f+g*x^2])/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x]

Int[(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  x*(d+e*Log[f+g*x^2])*(a+b*ArcCot[c*x]) - 
  2*e*g*Int[x^2*(a+b*ArcCot[c*x])/(f+g*x^2),x] + 
  b*c*Int[x*(d+e*Log[f+g*x^2])/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x]

2.  ∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx

1.  ∫(((d+e Log[f+g (x^2)]) (a+b ArcTan[c x]))/x)dx

1.  ∫((Log[f+g (x^2)] (a+b ArcTan[c x]))/x)dx

1.  ∫((Log[f+g (x^2)] ArcTan[c x])/x)dx  when  (c^2)f+g==0

1:  ∫((Log[f+g (x^2)] ArcTan[c x])/x)dx  when  g==(c^2)f

Derivation: Piecewise constant extraction and algebraic simplification

Basis: If  g==(c^2)f, then (∂_x)(Log[f+g (x^2)]-Log[1-i c x]-Log[1+i c x])==0

Basis: (Log[1-i c x]+Log[1+i c x]) ArcTan[c x]==(i/2) ((Log[1-i c x])^2)-(i/2) ((Log[1+i c x])^2)

Rule: If  g==(c^2)f, then

∫((Log[f+g (x^2)] ArcTan[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[1-i c x]-Log[1+i c x])∫((ArcTan[c x])/x)dx+∫(((Log[1-i c x]+Log[1+i c x]) ArcTan[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[1-i c x]-Log[1+i c x])∫((ArcTan[c x])/x)dx+(i/2) ∫(((Log[1-i c x])^2)/x)dx-(i/2) ∫(((Log[1+i c x])^2)/x)dx

Int[Log[f_.+g_.*x_^2]*ArcTan[c_.*x_]/x_,x_Symbol] :=
  (Log[f+g*x^2]-Log[1-I*c*x]-Log[1+I*c*x])*Int[ArcTan[c*x]/x,x] + I/2*Int[Log[1-I*c*x]^2/x,x] - I/2*Int[Log[1+I*c*x]^2/x,x] /;
FreeQ[{c,f,g},x] && EqQ[g,c^2*f]

2:  ∫((Log[f+g (x^2)] ArcCot[c x])/x)dx  when  g==(c^2)f

Derivation: Piecewise constant extraction and algebraic simplification

Basis: If  g==(c^2)f, then (∂_x)(Log[f+g (x^2)]-Log[(c^2) (x^2)]-Log[1-(i/(c x))]-Log[1+(i/(c x))])==0

Basis: (Log[(c^2) (x^2)]+Log[1-(i/(c x))]+Log[1+(i/(c x))]) ArcCot[c x]==Log[(c^2) (x^2)] ArcCot[c x]+(i/2) ((Log[1-(i/(c x))])^2)-(i/2) ((Log[1+(i/(c x))])^2)

Rule: If  g==(c^2)f, then

∫((Log[f+g (x^2)] ArcCot[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[(c^2) (x^2)]-Log[1-(i/(c x))]-Log[1+(i/(c x))])∫((ArcCot[c x])/x)dx+∫(((Log[(c^2) (x^2)]+Log[1-(i/(c x))]+Log[1+(i/(c x))]) ArcCot[c x])/x)dx  ⟶  

(Log[f+g (x^2)]-Log[(c^2) (x^2)]-Log[1-(i/(c x))]-Log[1+(i/(c x))]) ∫((ArcCot[c x])/x)dx+∫((Log[(c^2) (x^2)] ArcCot[c x])/x)dx+(i/2) ∫(((Log[1-(i/(c x))])^2)/x)dx-(i/2) ∫(((Log[1+(i/(c x))])^2)/x)dx

Program code:

Int[Log[f_.+g_.*x_^2]*ArcCot[c_.*x_]/x_,x_Symbol] :=
  (Log[f+g*x^2]-Log[c^2*x^2]-Log[1-I/(c*x)]-Log[1+I/(c*x)])*Int[ArcCot[c*x]/x,x] + 
  Int[Log[c^2*x^2]*ArcCot[c*x]/x,x] + 
  I/2*Int[Log[1-I/(c*x)]^2/x,x] - 
  I/2*Int[Log[1+I/(c*x)]^2/x,x] /;
FreeQ[{c,f,g},x] && EqQ[g,c^2*f]

2:  ∫((Log[f+g (x^2)] (a+b ArcTan[c x]))/x)dx

Derivation: Algebraic expansion

Rule:

∫((Log[f+g (x^2)] (a+b ArcTan[c x]))/x)dx  ⟶  a ∫((Log[f+g (x^2)])/x)dx+b ∫((Log[f+g (x^2)] ArcTan[c x])/x)dx

Program code:

Int[Log[f_.+g_.*x_^2]*(a_+b_.*ArcTan[c_.*x_])/x_,x_Symbol] :=
  a*Int[Log[f+g*x^2]/x,x] + b*Int[Log[f+g*x^2]*ArcTan[c*x]/x,x] /;
FreeQ[{a,b,c,f,g},x]

Int[Log[f_.+g_.*x_^2]*(a_+b_.*ArcCot[c_.*x_])/x_,x_Symbol] :=
  a*Int[Log[f+g*x^2]/x,x] + b*Int[Log[f+g*x^2]*ArcCot[c*x]/x,x] /;
FreeQ[{a,b,c,f,g},x]

2:  ∫(((d+e Log[f+g (x^2)]) (a+b ArcTan[c x]))/x)dx

Derivation: Algebraic expansion

Rule:

∫(((d+e Log[f+g (x^2)]) (a+b ArcTan[c x]))/x)dx  ⟶  d ∫((a+b ArcTan[c x])/x)dx+e ∫((Log[f+g (x^2)] (a+b ArcTan[c x]))/x)dx

Program code:

Int[(d_+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTan[c_.*x_])/x_,x_Symbol] :=
  d*Int[(a+b*ArcTan[c*x])/x,x] + e*Int[Log[f+g*x^2]*(a+b*ArcTan[c*x])/x,x] /;
FreeQ[{a,b,c,d,e,f,g},x]

Int[(d_+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCot[c_.*x_])/x_,x_Symbol] :=
  d*Int[(a+b*ArcCot[c*x])/x,x] + e*Int[Log[f+g*x^2]*(a+b*ArcCot[c*x])/x,x] /;
FreeQ[{a,b,c,d,e,f,g},x]

2:  ∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx  when  (m/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts

Rule: If (m/2)∈ℤ, then

∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx  ⟶  
(((x^(m+1))(d+e Log[f+g (x^2)])(a+b ArcTan[c x]))/(m+1))-((2e g)/(m+1))∫(((x^(m+2))(a+b ArcTan[c x]))/(f+g (x^2)))dx-((b c)/(m+1))∫(((x^(m+1))(d+e Log[f+g (x^2)]))/(1+(c^2) (x^2)))dx

Program code:

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  x^(m+1)*(d+e*Log[f+g*x^2])*(a+b*ArcTan[c*x])/(m+1) - 
  2*e*g/(m+1)*Int[x^(m+2)*(a+b*ArcTan[c*x])/(f+g*x^2),x] - 
  b*c/(m+1)*Int[x^(m+1)*(d+e*Log[f+g*x^2])/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && ILtQ[m/2,0]

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  x^(m+1)*(d+e*Log[f+g*x^2])*(a+b*ArcCot[c*x])/(m+1) - 
  2*e*g/(m+1)*Int[x^(m+2)*(a+b*ArcCot[c*x])/(f+g*x^2),x] + 
  b*c/(m+1)*Int[x^(m+1)*(d+e*Log[f+g*x^2])/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && ILtQ[m/2,0]

3:  ∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx  when  ((m+1)/2)∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If ((m+1)/2)∈(SuperPlus[ℤ]), let u=∫(x^m)(d+e Log[f+g (x^2)])dx, then

∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx  ⟶  u (a+b ArcTan[c x])-b c∫(u/(1+(c^2) (x^2)))dx

Program code:

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*Log[f+g*x^2]),x]},  
  Dist[a+b*ArcTan[c*x],u,x] - b*c*Int[ExpandIntegrand[u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[(m+1)/2,0]

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*Log[f+g*x^2]),x]},  
  Dist[a+b*ArcCot[c*x],u,x] + b*c*Int[ExpandIntegrand[u/(1+c^2*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IGtQ[(m+1)/2,0]

4:  ∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx  when  m∈ℤ

Derivation: Integration by parts

Rule: If  m∈ℤ, let u=∫(x^m)(a+b ArcTan[c x])dx, then

∫(x^m)(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx  ⟶  u (d+e Log[f+g (x^2)])-2 e g∫((x u)/(f+g (x^2)))dx

Program code:

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcTan[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(a+b*ArcTan[c*x]),x]},  
  Dist[d+e*Log[f+g*x^2],u,x] - 2*e*g*Int[ExpandIntegrand[x*u/(f+g*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IntegerQ[m] && NeQ[m,-1]

Int[x_^m_.*(d_.+e_.*Log[f_.+g_.*x_^2])*(a_.+b_.*ArcCot[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[x^m*(a+b*ArcCot[c*x]),x]},  
  Dist[d+e*Log[f+g*x^2],u,x] - 2*e*g*Int[ExpandIntegrand[x*u/(f+g*x^2),x],x]] /;
FreeQ[{a,b,c,d,e,f,g},x] && IntegerQ[m] && NeQ[m,-1]

3:  ∫x (d+e Log[f+g (x^2)])(((a+b ArcTan[c x]))^2)dx  when  g==(c^2)f

Derivation: Integration by parts

Basis: x (d+e Log[f+g (x^2)])==(∂_x)((((f+g (x^2)) (d+e Log[f+g (x^2)]))/(2 g))-((e (x^2))/2))

Rule: If  g==(c^2)f, then

∫x (d+e Log[f+g (x^2)])(((a+b ArcTan[c x]))^2)dx  ⟶  
(((f+g (x^2))(d+e Log[f+g (x^2)])(((a+b ArcTan[c x]))^2))/(2 g))-((e (x^2)(((a+b ArcTan[c x]))^2))/2)-(b/c)∫(d+e Log[f+g (x^2)])(a+b ArcTan[c x])dx+b c e∫(((x^2)(a+b ArcTan[c x]))/(1+(c^2) (x^2)))dx

Program code:

Int[x_*(d_.+e_.*Log[f_+g_.*x_^2])*(a_.+b_.*ArcTan[c_.*x_])^2,x_Symbol] :=
  (f+g*x^2)*(d+e*Log[f+g*x^2])*(a+b*ArcTan[c*x])^2/(2*g) - 
  e*x^2*(a+b*ArcTan[c*x])^2/2 - 
  b/c*Int[(d+e*Log[f+g*x^2])*(a+b*ArcTan[c*x]),x] + 
  b*c*e*Int[x^2*(a+b*ArcTan[c*x])/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[g,c^2*f]

Int[x_*(d_.+e_.*Log[f_+g_.*x_^2])*(a_.+b_.*ArcCot[c_.*x_])^2,x_Symbol] :=
  (f+g*x^2)*(d+e*Log[f+g*x^2])*(a+b*ArcCot[c*x])^2/(2*g) - 
  e*x^2*(a+b*ArcCot[c*x])^2/2 + 
  b/c*Int[(d+e*Log[f+g*x^2])*(a+b*ArcCot[c*x]),x] - 
  b*c*e*Int[x^2*(a+b*ArcCot[c*x])/(1+c^2*x^2),x] /;
FreeQ[{a,b,c,d,e,f,g},x] && EqQ[g,c^2*f]

U:  ∫u(((a+b ArcTan[c x]))^p)dx

Rule:

∫u(((a+b ArcTan[c x]))^p)dx  ⟶  ∫u(((a+b ArcTan[c x]))^p)dx

Program code:

Int[u_.*(a_.+b_.*ArcTan[c_.*x_])^p_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcTan[c*x])^p,x] /;
FreeQ[{a,b,c,p},x] && (EqQ[u,1] || 
  MatchQ[u,(d_.+e_.*x)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x)^q_./; FreeQ[{d,e,f,m,q},x]] || 
  MatchQ[u,(d_.+e_.*x^2)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x^2)^q_./; FreeQ[{d,e,f,m,q},x]])

Int[u_.*(a_.+b_.*ArcCot[c_.*x_])^p_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcCot[c*x])^p,x] /;
FreeQ[{a,b,c,p},x] && (EqQ[u,1] || 
  MatchQ[u,(d_.+e_.*x)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x)^q_./; FreeQ[{d,e,f,m,q},x]] || 
  MatchQ[u,(d_.+e_.*x^2)^q_./; FreeQ[{d,e,q},x]] || 
  MatchQ[u,(f_.*x)^m_.*(d_.+e_.*x^2)^q_./; FreeQ[{d,e,f,m,q},x]])